Sample program for reading the Master data file on CARES case characteristics and resident parent demographics

/***************************************
 Sample SAS command file for using CSDE Administrative Public Use Data
 Master File on Resident Parents
 ************************************/ 

%include "PUlib.sas"; *this line is necessary in order to access the    
             Public Use data;

/***************************************
        Read in Resident Parent and CARES W-2 cases file (Master A_BX).
        Select only cases in Analyze sample
   ************************************/

data AnalyzeSample;
   set puAD.MasterA_BX;
   if analyze eq 0; *this restricts the sample to child support-eligible
             cases appropriate for the CSDE analysis;
   run;

/***************************************
        Examine distribution of categorical variable
        RPEDUCB2 - Resident Parent's Education at W-2 Entry
   ************************************/

proc freq data=AnalyzeSample;
     table RPEDUCB2;
   run;

   /****************************************
        Examine means of continuous variable
        EARN8RP1A - Resident Parent's Average Annual Earnings in
        8 quarters before W-2 Entry 
        (as reported in Unemployment Insurance records)
   *************************************/

proc means N MEAN STD data=AnalyzeSample;
   var EARN8RP1A;
   where EARN8RP1A ge 0;
   run;

   /******************************************
        Compare means of continuous variable
        EARN8RP1A
        for cases receiving experimental or control treatments.
   
        Cases must be weighted by WEIGHT1 to reflect differential
        assignment into experimental and control groups.
   ********************************************/ 

proc ttest data=AnalyzeSample;
   class CRESGRP1;
   var EARN8RP1A;
   weight weight1;
   where CRESGRP1 in ("E","C") and EARN8RP1A ge 0;
   run;

/******************************************
        Compare means of continuous variable
        EARN8RP1A
        for cases receiving experimental/non-experimental
        or control treatments.

        Same as previous example except that non-experimental
        cases are included with the experimental cases
        since non-experimental cases received the same treatment
        as experimental cases.
   
        Cases must be weighted by WEIGHT2 to reflect differential
        assignment into experimental/non-experimental and control groups.
   ********************************************/ 

proc ttest data=AnalyzeSample;
   class CRESGRP2;
   var EARN8RP1A;
   weight weight2;
   where CRESGRP2 in ("EN","CC") and EARN8RP1A ge 0;
   run;

Return to top of page